=IFERROR(IsMacroEnabled(),FALSE)

Function IsMacroEnabled() As Boolean
    On Error GoTo NoMacro
    Application.EnableEvents = Application.EnableEvents
    IsMacroEnabled = True
    Exit Function
NoMacro:
    IsMacroEnabled = False
End Function

=LET(a,RNG1,b,RNG2,c,COLUMNS(a),d,COLUMNS(b),e,c+d,r,ROWS(a),IF(SEQUENCE(1,e)<=c,INDEX(a,SEQUENCE( r),SEQUENCE(1,c)), INDEX(b,SEQUENCE(r ),SEQUENCE(1,e)-c)))

Hoặc đặt hàm LAMBDA
HMerge =LAMBDA(d_1,d_2,LET(c_1,COLUMNS(d_1),c_2,COLUMNS(d_2),c_0,c_1+c_2,r,ROWS(d_1),IF(SEQUENCE(1,c_0)<=c_1,INDEX(d_1,SEQUENCE( r),SEQUENCE(1,c_1)),INDEX(d_2,SEQUENCE(r ),SEQUENCE(1,c_0)-c_1))))

và công thức =HMerge(HMerge(HMerge(B3:C5,E3:G5),HMerge(I3:K5,M3:O5)),HMerge(Q3:S5,A2:C4))

Đặt hàm LAMBDA
Append =LAMBDA(a,b,IF(SEQUENCE(ROWS(a)+ROWS(b))<=ROWS(a),INDEX(a,SEQUENCE(ROWS(a)),{1,2}), INDEX(b,SEQUENCE(ROWS(a)+ROWS(b))-ROWS(a),{1,2})))

Và công thức
=Append(Append(Data1,Data2),Data3)

Cách dùng (ví dụ)

1. Dán công thức trên vào Name Manager đặt tên ví dụ SPILL_BY_ROWS (không bắt buộc).
   Hoặc gọi trực tiếp bằng cách kết thúc LAMBDA bằng (...params...) như ví dụ dưới.

2. Gọi LAMBDA trực tiếp trong ô (ví dụ dữ liệu ở A1:A100, max mỗi cột 10 dòng):

FILTERS (phiên bản 1 điều kiện)

*  = bất kỳ chuỗi ký tự nào
?  = một ký tự bất kỳ
~* = ký tự * thật
~? = ký tự ? thật

=LAMBDA(array, by_array, criteria, [if_empty],
  LET(
    include,
      MAP(by_array, LAMBDA(x, --(SUM(COUNTIF(x, criteria))>0))),
    FILTER(array, include, IF(ISOMITTED(if_empty), "", if_empty))
  )
)

=LAMBDA(String,Keyword,LET(     k,TEXTSPLIT(Keyword,";"),     SUM(--ISNUMBER(SEARCH(TRIM(k),String)))>0 ))

=LAMBDA(String,Keyword,IFERROR(LET(
    k,TEXTSPLIT(Keyword,";"),
    SUM(--ISNUMBER(SEARCH(TRIM(k),String)))>0
),FALSE))

Hàm PICKCOLS là một hàm LAMBDA dùng để trích xuất một hoặc nhiều cột từ vùng dữ liệu động (dynamic array) theo tên cột, mà không cần chỉ định thủ công vị trí cột.

=LAMBDA(data,cols,LET(h,TAKE(OFFSET(data,-1,0),1),CHOOSECOLS(data,XMATCH(cols,h))))

IFNULL=LAMBDA(x,value_if_null,IF(OR(ISBLANK(x),x=""),value_if_null,x))

BETWEEN=LAMBDA(x,min,max,AND(x>=min,x<=max))

=LAMBDA(data_table,headers_in_arrow_bracket,CHOOSECOLS(data_table, XMATCH(headers_in_arrow_bracket, TAKE(data_table,1))))

=LET(table,A1:E4,CHOOSECOLS(table, XMATCH({"code","quantity","amount"},table))

Hàm trả về danh sách tháng

ngay_hom_nay as date
so_thang_truoc as number
so_thang_sauy as number

LASTNUM=LAMBDA(range, TAKE(FILTER(range,(range<>0)*(range<>"")),-1))

FIRSTNUM=LAMBDA(range, TAKE(FILTER(range,(range<>0)*(range<>"")),1))

SUMROW=LAMBDA(range,BYROW(range,SUM))

SUMCOL=LAMBDA(range,BYCOL(range,SUM))

AVERAGEROW=LAMBDA(range,BYROW(range,AVERAGE))

AVERAGECOL=LAMBDA(range,BYCOL(range,AVERAGE))

MAXROW=LAMBDA(range,BYROW(range,MAX))

MAXCOL=LAMBDA(range,BYCOL(range,MAX))

MINROW=LAMBDA(range,BYROW(range,MIN))

MINCOL=LAMBDA(range,BYCOL(range,MIN))

COUNTROW
=LAMBDA(range,BYROW(range,COUNT))

COUNTCOL=LAMBDA(range,BYCOL(range,COUNT))

COUNTAROW=LAMBDA(range,BYROW(range,COUNTA))

COUNTACOL=LAMBDA(range,BYCOL(range,COUNTA))

APPLYROW=LAMBDA(range,func,BYROW(range,func))

APPLYCOL=LAMBDA(range,func,BYCOL(range,func))

SUMIFROW
=LAMBDA(range,cond_range,cond,
    BYROW(range,LAMBDA(r,
        SUM(IF(cond_range=cond,r))
    ))
)

SUMIFCOL
=LAMBDA(range,cond_range,cond,
    BYCOL(range,LAMBDA(c,
        SUM(IF(cond_range=cond,c))
    ))
)

COUNTIFROW
=LAMBDA(range,cond,
    BYROW(range,LAMBDA(r,
        COUNTIF(r,cond)
    ))
)

COUNTIFCOL
=LAMBDA(range,cond,
    BYCOL(range,LAMBDA(c,
        COUNTIF(c,cond)
    ))
)

UNIQUECOUNTROW
=LAMBDA(range,
    BYROW(range,LAMBDA(r,COUNTA(UNIQUE(r))))
)

UNIQUECOUNTCOL
=LAMBDA(range,
    BYCOL(range,LAMBDA(c,COUNTA(UNIQUE(c))))
)

TOPNROW
=LAMBDA(range,n,
    BYROW(range,LAMBDA(r,LARGE(r,n)))
)

TOPNCOL
=LAMBDA(range,n,
    BYCOL(range,LAMBDA(c,LARGE(c,n)))
)

BOTTOMNROW
=LAMBDA(range,n,
    BYROW(range,LAMBDA(r,SMALL(r,n)))
)

BOTTOMNCOL
=LAMBDA(range,n,
    BYCOL(range,LAMBDA(c,SMALL(c,n)))
)

GROUPSUM
=LAMBDA(keys,values,
    LET(
        u,UNIQUE(keys),
        sums,MAP(u,LAMBDA(k,SUM(FILTER(values,keys=k)))),
        HSTACK(u,sums)
    )
)

APPLYROW
=LAMBDA(range,func,BYROW(range,func))

APPLYCOL
=LAMBDA(range,func,BYCOL(range,func))

APPLY
=LAMBDA(range,func,MAP(range,func))

👉 Trả về bảng pivot hoàn chỉnh (có header).

PIVOTSUM
=LAMBDA(row_keys,col_keys,values,
    LET(
        r,UNIQUE(row_keys),
        c,UNIQUE(col_keys),
        body,
            MAKEARRAY(
                ROWS(r),
                COLUMNS(c),
                LAMBDA(i,j,
                    SUMIFS(
                        values,
                        row_keys,INDEX(r,i),
                        col_keys,INDEX(c,j)
                    )
                )
            ),
        VSTACK(
            HSTACK("",c),
            HSTACK(r,body)
        )
    )
)

GROUPSUM2
=LAMBDA(key1,key2,values,
    LET(
        combo,UNIQUE(HSTACK(key1,key2)),
        sums,
            MAP(
                TAKE(combo,,1),
                TAKE(combo,,2),
                LAMBDA(k1,k2,
                    SUMIFS(values,key1,k1,key2,k2)
                )
            ),
        HSTACK(combo,sums)
    )
)

GROUPSUM3
=LAMBDA(key1,key2,key3,values,
    LET(
        combo,UNIQUE(HSTACK(key1,key2,key3)),
        sums,
            MAP(
                TAKE(combo,,1),
                TAKE(combo,,2),
                TAKE(combo,,3),
                LAMBDA(k1,k2,k3,
                    SUMIFS(values,key1,k1,key2,k2,key3,k3)
                )
            ),
        HSTACK(combo,sums)
    )
)

GROUPBY
=LAMBDA(keys,values,
    LET(
        u,UNIQUE(keys),
        sums,
            MAP(
                u,
                LAMBDA(k,
                    SUM(FILTER(values,keys=k))
                )
            ),
        HSTACK(u,sums)
    )
)

=LET(b,range,
    prev,VSTACK("",TAKE(b,ROWS(b)-1)),
    grp,SCAN(0,SEQUENCE(ROWS(b)),
        LAMBDA(a,i,
            IF(INDEX(b,i)=INDEX(prev,i),a,a+1))),
    idx,MAP(SEQUENCE(ROWS(b)),
        LAMBDA(i,
            COUNTIF(INDEX(b,1):INDEX(b,i),INDEX(b,i)))),
    grp&"."&idx)